如何以编程方式添加数据环境到表单
作者：James 出处:网络

最后检查日期: January 22, 1996
文号: Q142885 本文信息应用于:
Microsoft Visual FoxPro for Windows, versions 3.0 and 3.0b

概述
在用表单设计器创建表时, 数据环境对象被自动添加到表单. 要在编程方式建立的表单中模仿该行为, 在表单中必须定义一个 DataEnvironment 属性. 然后一个指向数据环境的对象可以保存在表单的 DataEnvironment 属性中.

更多信息

建立一个新的程序并打入以下代码:
oform1=CREATEOBJECT("Myform") && 实例化表单 oform1.SHOW(0) oform1.refresh READ EVENTS RETURN

DEFINE CLASS Data1 AS dataenvironment &&数据环境类
Name = "Dataenvironment"
ADD OBJECT "Cursor1" AS MyCursor &&为数据环境中的各游标
ENDDEFINE &&添加 Cursor 类对象
DEFINE CLASS MyCursor AS cursor
Alias = "customer"
Database = "C:\vfp\samples\data\testdata.dbc"
CursorSource = "customer"
Name = "Cursor1"
ENDDEFINE
DEFINE CLASS Myform AS form
Top = 0
Left = 0
Height = 386
Width = 587
DoCreate = .T.
Caption = "Form1"
Name = "FORM1"
DataEnvironment="" &&DataEnvironment 是表单的一个属性

PROCEDURE Destroy
WAIT WINDOW PROGRAM() TIMEOUT 2
THISFORM.DATAENVIRONMENT.CLOSETABLES &&在 destroy 过程的结束处关闭表
ENDPROC
PROCEDURE Unload
CLEAR EVENTS
ENDPROC
PROCEDURE Load
* DataEnvironment 被实例化,且表单的属性
* DataEnvironment 引用该对象. DataEnvironment
* 并没有实际地添加到表单. THISFORM.DATAENVIRONMENT
* 只是一个指向 DataEnvironment 对象的指针.
THISFORM.DATAENVIRONMENT=CREATEOBJECT("Data1")
* 在 LOAD 开始时打开表.
THISFORM.DATAENVIRONMENT.OPENTABLES
WAIT WINDOW PROGRAM() TIMEOUT 2
ENDPROC
ENDDEFINE

打开调试窗口.

在调试窗口中打入以下命令
_SCREEN.ACTIVEFORM.DATAENVIRONMENT.NAME

运行第一步中创建的程序.

注意调试窗口正确地显示 Dataenvironment 作为 _SCREEN.ACTIVEFORM.DATAENVIRONMENT.NAME 值的 Dataenvironment

[返回]

首页 | 设为首页 | 加入收藏 | 关于本站 | 友情链接 | 版权声明